编写 pptp 连接批处理

使用说明

使用的时候，先搜索 serverIp，把这个改成你的 vpn 服务器的 ip，域名也可以，然后搜索 zhanghao,mima 并分别替换为你的 vpn 账号和密码
替换完成之后保存，运行就可以了，最好是右键管理员运行，否则可能无法添加路由表（这样访问国内的网站如百度也是会走 vpn 服务器的，所以会觉得访问百度变慢了），具体如何查看是否添加成功路由表了,cmd 中使用命令：route print
如果出来一大堆，那么你路由表已经添加成功了，如果没有或者只是少数的几个，那说明你没有添加成功，右键管理员运行吧（或者检查下 routes.txt 文件）。
如果路由表中已经有了添加进去的路由，只要不关机，它就会一直存在的，所以如果你批处理关闭了，下一次连接的时候如果是没有关过机的状态，直接选择全局代理就可以了。

使用说明：双击vpn.bat，输入1或者2，然后回车——>连接成功

直接放代码了

@echo off
setlocal enabledelayedexpansion
:Start
cls
echo ============================================================
echo 设置账号密码，右键本文件, 选择编辑，搜索"zhanghao","mima"，根据提示进行替换
echo=
echo 1: 全局代理（访问百度等国内网站稍慢）
echo 2: 海外代理（访问国内网站速度不受限制，但是ip还是当前ip，不是代理ip）
echo=
echo 3: 断开连接(不删除路由表)
echo ============================================================
set /p c=  选择代理方式:
if %c%==2 goto SetRoute
if %c%==3 goto DisConnect
:VPNConnect
rem if not exist "%AllUsersProfile%\Application Data\Microsoft\Network\Connections\Pbk\rasphone.pbk" (
    echo 新建VPN!
    md "%AllUsersProfile%\Application Data\Microsoft\Network\Connections\Pbk" 2>nul
    call :NewVPN "serverIp"
	rem 上面引号里面的就是服务器地址
rem  )
:Main
cls
rasdial VPN "zhanghao" "mima"
rem 上面引号里面的就是账号和密码
echo ===============
echo 1: 重新连接
echo 2: 断开连接(删除路由表，较慢)
echo 3: 断开连接(不删除路由表)
echo ===============
set /p c=  接下来的操作:
if %c%==2 goto DeleteRoutes
if %c%==1 goto Reconnect
if %c%==3 goto DisConnect
:SetRoute
for /f "tokens=2 delims=:" %%a in ('find /c /v "" routes.txt')do set/a result=%%a+0
set b=%result%
for /f "delims=" %%a in (routes.txt) do (
	cls
	set /a index+=1
	set /a jdt=!index!*100/%b%
	echo 路由表添加中
	echo 正在执行第!index!/%b% 条,!jdt!%%
    %%a 2>nul
)
goto VPNConnect
:NewVPN
(echo [VPN]
echo MEDIA=rastapi
echo Port=VPN4-0
echo Device=WAN Miniport (L2TP^)
echo DEVICE=vpn
echo PhoneNumber=%~1
)>"%AllUsersProfile%\Application Data\Microsoft\Network\Connections\Pbk\rasphone.pbk"
goto Main
:DeleteRoutes
for /f "tokens=2 delims=:" %%a in ('find /c /v "" routesDelete.txt')do set/a result=%%a+0
set b=%result%
for /f "delims=" %%a in (routesDelete.txt) do (
	cls
	set /a index+=1
	set /a jdt=!index!*100/%b%
	echo 路由表删除中
	echo 正在执行第!index!/%b% 条,!jdt!%%
    %%a 2>nul
)
goto DisConnect
:DisConnect
rasdial VPN /disconnect
goto Start
:Reconnect
rasdial VPN /disconnect
goto Start